| USB !Run file
|
| (c) 2002 Simtec Electronics
|
| $Id: !Run,feb,v 1.31 2003/12/01 17:28:26 ben Exp $

Run <Obey$Dir>.!Boot

Set USB$FirstLoad 0

If "<USB$Dir>" = "" Then Set USB$FirstLoad 1
If "<USB$Dir>" = "" Then Obey <Obey$Dir>.!SetupEnv

|
Iconsprites <Obey$dir>.!Sprites

|
| Auto Installation of Configuration Files at ROS 4.X
|

If "<Choices$Write>"="" Then Set USB$Choices False Else Set USB$Choices True

If "<USB$Choices>" = "True" Then Set USB$ChoicesDir <Choices$Write>.USB Else Set USB$ChoicesDir <USB$Dir>

| work out wether the core is loaded, and if so, if it is a new version
| of the core

Set USB$OldCore False
Set USB$CoreLoaded True

RMEnsure USB 1.06	Set USB$OldCore True
RMEnsure USB 0.00	Set USB$CoreLoaded False

Set USB$Old True

If "<USB$CoreLoaded>" = "False" Then Set USB$Old False
If "<USB$OldCore>" = "False" Then Set USB$Old False

If "<USB$Old>" = "True" Then Echo Old USB modules detected, please update flash
If "<USB$Old>" = "True" Then Run <Obey$Dir>.bin.USBStop

| ensure we have the latest modules loaded

| Core driver
RMEnsure USB 2.01              RMLoad System:Modules.USB.USBCore
RMEnsure USB 2.01              Error !USB requires USB 2.01 or later

| Hub driver
RMensure USBHub 2.01           RMLoad System:Modules.USB.USBHub
RMensure USBHub 2.01           Error !USB Requires USBHub 2.01 or later

| ISP1161 hardware driver
RMensure USBISP1161 2.01       RMLoad System:Modules.USB.USBISP1161
RMensure USBISP1161 2.01       Error !USB Requires USBISP1161 2.01 or later

| Support module
RMensure USBISP1161Support 1.00 RMLoad System:Modules.USB.USBSup1161
| note, we don't error if the support module is not loaded, as it is no
| longer necessary

| Extra modules, these do not need to be loaded, but are useful if they
| are.

RMEnsure USB_HIDInput 2.01     RMLoad System:Modules.USB.USBHidInp

RMEnsure USBLib 2.01 RMLoad System:Modules.USB.USBLib

Run <USB$Dir>.Support.RestartLog

| Ensure our task is started if we are in the wimp already

If "<Wimp$State>"="desktop" Then WimpTask USB_StartTask

